home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD014a.dsk / SOFTWARE.POLL.bas < prev    next >
BASIC Source File  |  2003-06-12  |  4KB  |  92 lines
  1. 10  REM  SOFTWARE.POLL
  2. 20 D$ =  CHR$(4)
  3. 30  TEXT : PRINT D$"NOMON C,I,O": SPEED= 255
  4. 100  PRINT D$;"OPEN POLL.TITLES"
  5. 110  PRINT D$;"READ POLL.TITLES"
  6. 120  INPUT PD$: INPUT NI
  7. 125  DIM TI$(NI),RT(NI)
  8. 130  FOR I = 1 TO NI: INPUT TI$(I): NEXT 
  9. 140  PRINT D$;"CLOSE POLL.TITLES"
  10. 150  PRINT D$;"OPEN POLL.RATINGS"
  11. 160  PRINT D$;"READ POLL.RATINGS"
  12. 170  INPUT PD$: INPUT RF
  13. 180  FOR I = 1 TO NI: INPUT RT(I): NEXT 
  14. 190  PRINT D$
  15. 500  GOSUB 6000
  16. 510  VTAB 3: PRINT "THIS POLL IS INTENDED TO MEASURE"
  17. 520  VTAB 5: PRINT "SOFTWARE SATISFACTION."
  18. 530  VTAB 8: PRINT "PLEASE VOTE ONLY FOR THAT SOFTWARE"
  19. 540  VTAB 10: PRINT "WHICH YOU OWN."
  20. 550  VTAB 13: PRINT "R<CTRL-A>ATE SOFTWARE ON A SCALE FROM 1 TO 10.
  21. 560  VTAB 15: PRINT "1=BAD";: HTAB 17: PRINT "5=OK";: HTAB 27: PRINT "10=EXCELLENT"
  22. 570  VTAB 18: PRINT "SOFTWARE COMES FROM THE SOFTALK"
  23. 580  VTAB 20: PRINT "BEST SELLER LIST."
  24. 590  GOSUB 7000
  25. 600  GOSUB 6000
  26. 610  VTAB 3: PRINT "USE THE I,J,K & M  KEYS TO MOVE ABOUT"
  27. 620  VTAB 5: PRINT "AND CAST YOUR VOTES."
  28. 630  VTAB 6: HTAB 21: INVERSE : PRINT "UP";: NORMAL 
  29. 640  VTAB 8: HTAB 21: PRINT "I";
  30. 650  VTAB 9: HTAB 15: INVERSE : PRINT "LEFT";: NORMAL : PRINT " J K ";: INVERSE : PRINT "RIGHT";: NORMAL 
  31. 660  VTAB 10: HTAB 21: PRINT "M";
  32. 670  VTAB 12: HTAB 20: INVERSE : PRINT "DOWN": NORMAL 
  33. 680  VTAB 14: PRINT "TO WITHDRAW A VOTE, MOVE OFF THE SCALE"
  34. 690  VTAB 16: PRINT "ON EITHER END."
  35. 700  VTAB 19: PRINT "WHEN YOU ARE READY TO REGISTER YOUR"
  36. 710  VTAB 21: PRINT "VOTES HIT THE RETURN KEY."
  37. 720  GOSUB 7000
  38. 730 I = 1
  39. 1000  GOSUB 5000
  40. 1020  VTAB ( PEEK(37) +1): HTAB 40: GET R$: PRINT D$
  41. 1030  IF R$ =  CHR$(13) GOTO 2500
  42. 1040  IF R$ = "I" GOTO 2300
  43. 1050  IF R$ = "M" GOTO 2200
  44. 1060  IF R$ = "J" GOTO 2100
  45. 1070  IF R$ = "K" GOTO 2000
  46. 1080  IF R$ = "H" GOTO 600
  47. 1090  VTAB ( PEEK(37)): GOTO 1020
  48. 2000 L = RT(I): VTAB (3 +2 *K): HTAB 20: PRINT "1 2 3 4 5 6 7 8 9 10";
  49. 2010 L = L +1: IF L >10  THEN L = 0
  50. 2020 RT(I) = L
  51. 2030  IF L < >0  THEN  HTAB (18 +2 *L): INVERSE : PRINT L;: NORMAL 
  52. 2040  GOTO 1020
  53. 2100 L = RT(I): VTAB (3 +2 *K): HTAB 20: PRINT "1 2 3 4 5 6 7 8 9 10";
  54. 2110 L = L -1: IF L <0  THEN L = 10
  55. 2120 RT(I) = L
  56. 2130  IF L < >0  THEN  HTAB (18 +2 *L): INVERSE : PRINT L;: NORMAL 
  57. 2140  GOTO 1020
  58. 2200 I = I +1:K = K +1:L = 0
  59. 2210  IF I >NI  THEN I = 1:K = 11
  60. 2220  IF K >10  THEN  GOSUB 5000: GOTO 1020
  61. 2230  VTAB (1 +2 *K): HTAB 1: PRINT TI$(I -1);
  62. 2240  VTAB (3 +2 *K): HTAB 1: INVERSE : PRINT TI$(I);: NORMAL 
  63. 2250  GOTO 1020
  64. 2300 I = I -1:K = K -1:L = 0
  65. 2310  IF I <1  THEN I = NI
  66. 2320  IF K <1  THEN I =  INT(I/10) *10 -9: GOSUB 5000: GOTO 1020
  67. 2330  VTAB (5 +2 *K): HTAB 1: PRINT TI$(I +1);
  68. 2340  VTAB (3 +2 *K): HTAB 1: INVERSE : PRINT TI$(I);: NORMAL 
  69. 2350  GOTO 1020
  70. 2500  PRINT D$;"CLOSE POLL.RATINGS"
  71. 2510  PRINT D$;"DELETE POLL.RATINGS"
  72. 2520  PRINT D$;"OPEN POLL.RATINGS"
  73. 2530  PRINT D$;"WRITE POLL.RATINGS"
  74. 2535 RF = 0: FOR I = 1 TO NI: IF RT(I) < >0  THEN RF = 1: NEXT 
  75. 2540  PRINT PD$: PRINT RF
  76. 2550  FOR I = 1 TO NI: PRINT RT(I): NEXT 
  77. 2560  PRINT D$;"CLOSE POLL.RATINGS"
  78. 2570  HOME : PRINT D$;"RUN KICK.IT.OFF"
  79. 5000  GOSUB 6000
  80. 5010  VTAB 3: HTAB 20: PRINT "BAD";: HTAB 36: PRINT "GOOD"
  81. 5020 J = I:K = 1
  82. 5055  VTAB (3 +2 *K): HTAB 1
  83. 5060  PRINT TI$(J);: HTAB 20: PRINT "1 2 3 4 5 6 7 8 9 10";
  84. 5065  IF RT(J) < >0  THEN  HTAB (18 +2 *RT(J)): INVERSE : PRINT RT(J);: NORMAL 
  85. 5070 J = J +1:K = K +1
  86. 5080  IF J >NI  OR K >10 GOTO 5100
  87. 5090  GOTO 5055
  88. 5100  VTAB 24: HTAB 2: INVERSE : PRINT "H = HELP";: HTAB 16: PRINT "RETURN = REGISTER VOTES";: NORMAL 
  89. 5110  VTAB 5: HTAB 1: INVERSE : PRINT TI$(I);: NORMAL :K = 1:L = 0
  90. 5115  RETURN 
  91. 6000  HOME : HTAB 14: INVERSE : PRINT "SOFTWARE POLL": NORMAL : RETURN 
  92. 7000  VTAB 24: HTAB 14: INVERSE : PRINT "HIT SPACE BAR";: NORMAL : GET R$: PRINT D$: RETURN